/*
  WiFlash_esp32 - Concept & electronics:    Phil Abeyta
                - System design & firmware: Kevin Matz
                
Uses a GPIO to control a lighting console over OSC, whilst also 
controlling an LED strobe light with DMX data recieved over sACN.

Copyright (c) 2020 Kevin Matz (kevin.matz@gmail.com)

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
*/

#include <WiFi.h>
#include "sacn.h"
#include <ArduinoOSC.h>
#include "strobe_esp32.h"


/*
 * This section to be configured by Lighting Control
 */
// -----------------------------------
//   Configure the WiFi network
// -----------------------------------
const char ssid[] = "........";
const char pwd[] = "........";

// -----------------------------------
//   Configure the IPv4 network
// -----------------------------------
const IPAddress ip(127, 0, 0, 1);
const IPAddress subnet(255, 255, 255, 0);
const IPAddress gateway(127, 0, 0, 1);

// -----------------------------------
//   Configure OSC
// -----------------------------------
const String host = "127.0.0.1";
const uint16_t port = 7001;
const String pressed_addr = "/hog/playback/go/0";
const String pressed_value = "99.1";
const String released_addr = "/hog/playback/go/0";
const String released_value = "99.2";

// -----------------------------------
//   Configure E1.31 sACN
// -----------------------------------
Strobe strobe(E131_UNICAST, 1, 001); // (uni|multi)cast, sACN Universe, Address
/*                        DMX      Value    
 *  | chan | Command   | range |   range    |
 *  |------+-----------+-------+------------|
 *  |  1   | Intensity |   0-  |   0-100%   | 15 bit 2.4kHz PWM
 *  |  2   | fine      | 65535 |            |
 *  |------+-----------+-------+------------|
 *  |  3   | Duration  | 0-255 |  0.02-0.5s | 0.002s resolution
 *  |------+-----------+-------+------------|
 *  |  4   | Rate      | 0-255 |  0.5-25hz  | 0.1 hz resolution
 *  |------+-----------+-------+------------|
 */
 

/* 
 * This section to be configured by the Fixtures Dept.
 */
const int button = A0;        // A0, use 100nF to ground
const int led = LED_BUILTIN;  // IO13


/*
 * Change nothing else unless you're really sure.
 */

//// Global button variables
bool pressed = false;    // track button state
uint32_t change_time;    // time of button press (ms)


/*
 * Arduino powerup
 */
void setup() {
  Serial.begin(115200);

//// start WiFi:
  // set IPv4
  WiFi.mode(WIFI_STA);
  WiFi.config(ip, gateway, subnet);
  WiFi.begin(ssid, pwd);

  // join 802.11
  if (WiFi.config(ip, gateway, subnet)) {
    Serial.print("Connected to ");
    Serial.println(ssid);
    Serial.print("IP address is ");
    Serial.println(WiFi.localIP());
  } else {
    Serial.println("STA Failed to configure");
  }

  
//// start fixtures hardware:
  // button
  pinMode(button, INPUT_PULLUP);
  // led_trigPres_trigPress _trigPress _trigPress _trigPress s 
  if (!strobe.begin(led, 0)) {
    Serial.println("Strobe failed to configure.");
  }
}


/* 
 *  Arduino process loop
 */
void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("Waiting for WiFi...");
    delay(1000);
    return;
  }

  strobe.update();

  // Be a remote trigger
  //
  bool val = !digitalRead(button);
  if (val != pressed) {
    pressed = val;
    change_time = millis();
    if (pressed) {
      Serial.println("Pressed");
      OscWiFi.send(host, port, pressed_addr, pressed_value);
    } else {
      Serial.println("Released");
      OscWiFi.send(host, port, released_addr, released_value);
    }
  }
}