WiFlasher/wiflash_esp32/wiflash_esp32.ino

/*
  WiFlash_esp32 - Concept & electronics:    Phil Abeyta
                - System design & firmware: Kevin Matz

  Uses a GPIO to control a lighting console over OSC, whilst also
  controlling an LED strobe light with DMX data recieved over sACN.

  Copyright (c) 2020 Kevin Matz (kevin.matz@gmail.com)

  Permission is hereby granted, free of charge, to any person obtaining a copy
  of this software and associated documentation files (the "Software"), to deal
  in the Software without restriction, including without limitation the rights
  to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  copies of the Software, and to permit persons to whom the Software is
  furnished to do so, subject to the following conditions:

  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.

  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  SOFTWARE.
*/

#include <Arduino.h>
#include <WiFi.h>
#include <ArduinoOSC.h>
#include <NeoPixelBus.h>
#include <Preferences.h>
#include "sacn.h"
#include "strobe_esp32.h"
#include "dmx_universe.h"

/*
   If this pin is tied LOW at setup(), settings will be defaulted
*/
const int reset_button = A1;   // tie A1 to ground to reset preferances

/*
   device configuration
*/
struct config_ {
  String   ssid;
  String   pwd;
  wifi_mode_t mode;

  String   ip;
  String   subnet;
  String   gateway;
  String   hostname;

  String   osc_host;
  uint16_t osc_port;
  String   osc_pressed_addr;
  String   osc_pressed_value;
  String   osc_released_addr;
  String   osc_released_value;

  bool     button_enable;
  int      button_pin;

  bool     strobe_enable;
  int      strobe_led_pin;
  uint16_t strobe_universe;
  uint16_t strobe_address;

  bool     strip_enable;
  uint16_t strip_led_count;
  uint8_t  strip_data_pin;
  uint16_t strip_universe;
  uint16_t strip_address;
};
struct config_ config;


//// device objects
Strobe *strobe;
NeoPixelBus<NeoGrbwFeature, Neo800KbpsMethod> *strip;
ESPAsyncE131 *e131 = new ESPAsyncE131();
Preferences prefs;

//// Global button variables
bool pressed = false;    // track button state
uint32_t change_time;    // time of button press (ms)


/*
   change pixel strip colours on DMX change
*/
void recvPixelData(Universe *universe) {
  for (int i = 0; i < config.strip_led_count; i++) {
    uint8_t r, g, b, w;
    r = universe->data()->data[config.strip_address + (i * 4) + 0];
    g = universe->data()->data[config.strip_address + (i * 4) + 1];
    b = universe->data()->data[config.strip_address + (i * 4) + 2];
    w = universe->data()->data[config.strip_address + (i * 4) + 3];
    strip->SetPixelColor(i, RgbwColor(r, g, b, w));
  }
  strip->Show();
}


/*
   Change a setting in NVM
*/
bool changeSetting(String key, String val) {
  return true;
}

/*
   Load device configuration from NVM
*/
bool loadConfig() {
  prefs.begin("wiflash", false);  // open RW;

  Serial.print("Jump pin ");
  Serial.print(reset_button);
  Serial.println(" to GROUND to reset settings.");
  pinMode(reset_button, INPUT_PULLUP);
  if (prefs.getBool("reset_on_reboot") ||
      !digitalRead(reset_button)) {
    prefs.clear();
  }

  config.ssid = prefs.getString("ssid", "WiFlash");
  config.pwd  = prefs.getString("pwd", "technologyismagic");
  config.mode = (wifi_mode_t)prefs.getChar("wifi_mode", WIFI_AP);
  config.hostname = prefs.getString("hostname", "WiFlash");

  config.ip      = prefs.getString("ip", "192.168.1.1");
  config.subnet  = prefs.getString("subnet", "255.255.255.0");
  config.gateway = prefs.getString("gateway", "");

  config.button_enable = prefs.getBool("button_enable", true);
  config.button_pin    = prefs.getChar("butto_pin", A0);        // A0, use 100nF to ground

  config.osc_host           = prefs.getString("osc_host", "192.168.1.1");
  config.osc_port           = prefs.getShort("osc_port", 7001);
  config.osc_pressed_addr   = prefs.getString("osc_pressed_addr", "/hog/playback/go/0");
  config.osc_pressed_value  = prefs.getString("osc_pressed_value", "99.1");
  config.osc_released_addr  = prefs.getString("osc_released_addr", "/hog/playback/go/0");
  config.osc_released_value = prefs.getString("osc_released_value", "99.2");

  config.strobe_enable   = prefs.getBool("strobe_enable", true);
  config.strobe_led_pin  = prefs.getChar("strobe_led_pin", LED_BUILTIN);  // IO13
  config.strobe_universe = prefs.getShort("strobe_universe", 1);
  config.strobe_address  = prefs.getShort("strobe_address", 001);

  config.strip_enable    = prefs.getBool("strip_enable", false);
  config.strip_led_count = prefs.getShort("strip_led_count", 8);  // not less than 4
  config.strip_data_pin  = prefs.getChar("strip_data_pin", 21);
  config.strip_universe  = prefs.getShort("strip_universe", 1);
  config.strip_address   = prefs.getShort("strip_address", 001);

  return true;
}
}


/*
   Arduino powerup
*/
void setup() {
  Serial.begin(115200);
  while (!Serial); // wait for serial attach
  Serial.println("Serial started!");

  Serial.println("Loading Prefferences from NVM.");
  loadConfig();

  //// start WiFi:
  // set IPv4
  Serial.println("Starting WiFi.");
  WiFi.mode(WIFI_STA);
  WiFi.setHostname(config.hostname.c_str());
  IPAddress ip_, gateway_, subnet_;
  ip_.fromString(config.ip);
  gateway_.fromString(config.gateway);
  subnet_.fromString(config.subnet);
  WiFi.config(ip_, gateway_, subnet_);
  WiFi.begin(config.ssid.c_str(), config.pwd.c_str());

  Serial.println("Disabling Bluetooth.");
  btStop();


  //// start fixtures hardware:
  // button
  if (config.button_enable) {
    Serial.println("Initializing OSC button");
    pinMode(config.button_pin, INPUT_PULLUP);
  }

  // strobe
  if (config.strobe_enable) {
    strobe = new Strobe(config.strobe_address);
    Serial.println("Initializing DMX Strobe");
    if (!strobe->begin(config.strobe_led_pin, 0)) {
      Serial.println("Strobe failed to configure.");
    }
    if (e131->subscribe(config.strobe_universe)) {
      e131->universe(config.strobe_universe)->onData(std::bind(&Strobe::recvData,
          strobe, std::placeholders::_1));
    }
  }

  // pixels
  if (config.strip_enable) {
    Serial.println("Initializing Pixelmapped LEDs.");

    strip = new NeoPixelBus<NeoGrbwFeature, Neo800KbpsMethod>(config.strip_led_count, config.strip_data_pin);
    strip->Begin();
    strip->Show();
    if (e131->subscribe(config.strip_universe)) {
      e131->universe(config.strip_universe)->onData(std::bind(&recvPixelData,
          std::placeholders::_1));
    }
  }

  Serial.println("Setup complete!");
}


/*
    Arduino process loop
*/
void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("Waiting for WiFi...");
    delay(1000);
    return;
  }

  // Be a remote trigger
  //
  bool val = !digitalRead(config.button_pin);
  if (val != pressed && config.button_enable) {
    pressed = val;
    change_time = millis();
    if (pressed) {
      Serial.println("Pressed");
      OscWiFi.send(config.osc_host, config.osc_port,
                   config.osc_pressed_addr, config.osc_pressed_value);
    } else {
      Serial.println("Released");
      OscWiFi.send(config.osc_host, config.osc_port,
                   config.osc_released_addr, config.osc_released_value);
    }
  }
}